adfind -b "dc=domena,dc=cz" -f "objectcategory=person" proxyAddresses -nodn | findstr /i "smtp" > emails.txt
http://www.joeware.net/freetools/tools/adfind/index.htm
Script disable user acount and remove all groups from memberOf attribute except „Domain Users“.
@echo off
setlocal enableextensions enabledelayedexpansion
set tmp1=temp1.txt
set tmp2=temp2.txt
:user
set user=""
set /p user=Login :
if /I %user%=="" goto user
:start
set log=%user%.log
echo [%date% %time%] >> %log%
net user %user% /active:no /domain
dsquery user -samid %user% | dsget user -memberof | dsget group -samid > %tmp1%
type %tmp1% >> %log%
findstr /i /v "samid" %tmp1% | findstr /i /v "dsget succeeded" | findstr /c:"domain users" /i /v > %tmp2%
del %tmp1%
for /f "tokens=* delims= " %%a in ('type %tmp2%') do echo %%a >> %tmp1%
del %tmp2%
for /f "delims=" %%x in ('type %tmp1%') do (
set "str=%%x"
for /l %%a in (1,1,256) do if "!str:~-1!"==" " set "str=!str:~0,-1!"
echo.!str!>> %tmp2%
)
for /f "tokens=1 delims=" %%a in (%tmp2%) do (
net group "%%a" %user% /delete /domain
net localgroup "%%a" %user% /delete /domain
)
echo. >> %log% & echo [%date% %time%] >> %log%
dsquery user -samid %user% | dsget user -memberof | dsget group -samid >> %log%
del /f /q %tmp1% %tmp2%
Jednoduchá kontrola požadovaných služeb na zadaných serverech. Používá se psservice.exe a postie.exe pro odeslání upozornění e-mailem – na spouštěném stroji je nutný otevřený port TCP 25.
echo off
set conf=sluzby.ini
set log=sluzby.log
set mail_komu=administrator@%userdnsdomain%
set smtp_server=192.168.2.100
set zprava=zkontrolujte nastaveni popsane sluzby
set poslimail=postie -host:%smtp_server% -to:%mail_komu% -msg:"%zprava%"
for /f "eol=# tokens=1-2 delims= " %%a in (%conf%) do (
psservice \\%%a query %%b | findstr /i "state" | findstr /i "running"
if errorlevel 1 (
%poslimail% -s:"Sluzba %%b nebezi" -from:%%a@%userdnsdomain% >> %log%
echo [%date%, %time%] %%a %%b CHYBA >> %log%
) else (
echo [%date%, %time%] %%a %%b OK >> %log%
)
)
Příklad kontrolního souboru ‚sluzby.ini‘
#Konfiguracni soubor pro kontrolu sluzeb
#
#syntaxe:
#nazev_serveru nazev_sluzby
#
#priklad:
#serv1 wuauclt
#AV sluzby
192.168.1.30 mcafeeframework
192.168.1.30 mcshield
192.168.1.30 mctaskmanager
#Printspooler na PDC
192.168.1.10 spooler